(Fishing) Comprehensive Fishing Macro

[Experience]

This is a comprehensive fishing macro, you'll need 2 separate macros' :

Fishing Start

Fishing Bottle (Note: You must name this macro 'Fishing Bottle', as the first macro calls it)





* This assumes you have archery and magery.  Can easily be changed to use bandages instead

* Make sure you loop the first macro

* This only stops for bottles, however you could easily modify it to stop for any system message (nets, maps, etc).

* Additionally for the sounds to work they need to be in /uosteam/sounds/

Sound Files: fishing.zip

####################################################

####################################################

Fishing Start:

//Author: Lopsang

if not @listexists 'xaxis'

 @createlist 'xaxis'

 @pushlist 'xaxis' 3

 @pushlist 'xaxis' -3

endif

if not @listexists 'yaxis'

 @createlist 'yaxis'

 @pushlist 'yaxis' 3

 @pushlist 'yaxis' -3

endif

if not listexists 'fish'

 createlist 'fish'

 @pushlist 'fish' '0x9ce'

 @pushlist 'fish'' 0x9cf'

 @pushlist 'fish' '0x9cc'

 @pushlist 'fish' '0x9cd'

endif

while dead

 playsound 'error.wav'

 pause 8000

endwhile

if not @findobject 'bow'

 promptalias 'bow'

endif

if not @findobject 'lefthand'

 equipitem 'bow' 2

endif

if not @findobject 'pole' and @findtype 0xdbf 0x0 'self'

 setalias 'pole' 'found'

endif

for 0 to 'xaxis'

 for 0 to 'yaxis'

   while not @injournal 'biting' 'system'

     while dead

       playsound 'error.wav'

       pause 8000

     endwhile

     @canceltarget

     @useobject 'pole'

     waitfortarget 2000

     targettileoffset! 'xaxis[]' 'yaxis[]' 0

     pause 500

     if not @injournal 'biting' 'system'

       pause 7750

     endif

     if @injournal 'pull a bottle' 'system'

       clearjournal

       playmacro 'Fishing Bottle'

     endif

     if @injournal 'mess' 'system'

       clearjournal

       @usetype! 0xdd6

       pause 1000

       @usetype! 0xdd6

       pause 1000

     endif

     if @injournal 'closer' 'system'

       clearjournal

       resync

     endif

     //fishing cleanup

     if weight >= maxweight

       for 0 to 'fish'

         while @findtype fish[] 'any' 'backpack'

           usetype! 0xf52

           waitfortarget 1000

           target! 'found'

           pause 600

         endwhile

       endfor

       // adds to fishsteak pile on floor

       if @findtype 0x97a 'any' 'ground' 'any' 2

         movetype 0x97a 'backpack' 'found'

         pause 600

       else

         //starts fishsteak pile on floor if doesnt exist

         movetypeoffset 0x97a 'backpack'  'ground'

         pause 600

       endif

     endif

     //end fishing cleanup

     while diffhits > 30 and not dead

       autotargetself

       bigheal

       pause 1500

       if not @findobject 'lefthand'

         equipitem 'bow' 2

       endif

     endwhile

     getenemy 'gray' 'criminal' 'closest'

     if @inrange 'enemy' 10

       @autotargetenemy

       attack 'enemy'

     endif

   endwhile

   clearjournal

 endfor

 clearjournal

endfor

msg 'forward'

pause 4000

msg 'stop'

####################################################

####################################################

Fishing Bottle:

//Author: Lopsang

while diffhits > 30 and not dead

 autotargetself

 bigheal

 pause 1500

endwhile

pause 4000

getenemy 'gray' 'criminal' 'closest'

while @findobject 'enemy'

 if @inrange 'enemy' 10

   @autotargetenemy

   attack 'enemy'

 endif

endwhile

if not @findobject 'bow'

 promptalias 'bow'

endif

if not @findobject 'lefthand'

 equipitem 'bow' 2

endif

pause 4000

if dead

 playsound 'error.wav'

else

 playsound 'alert.wav'

endif

[krypher]

HI Experience
I am trying to get this script to work and so far some of it does. question, what and how are the yaxis and xaxis work? and how do I change (if needed) to work on the server I play? The fish, I keep adding them to the @pushlist but some of them have the same Graphics number I check in active objects and the new fish are not listed, I use the dagger that is listed in the script. What are you using to cut fish? after I kill the serpent does this script move to corpse and loots? so far all it does is kill then goes back to fishing. I would like this script to kill, loot, then back to fishing? (Yes AFK is allowed on my server). In my pack I keep a Dagger, Bow and Bolts, fish pole. I am a Archer/Mage
Thanks
Krypher

[krypher]

OK I got the cut fish to work. But have to manually walk to corpse of serpent to loot. I have set my autoloot to collect the nets and MIB's for now.

[Experience]

The script is not meant to move to corpse and loot.

[krypher]

can it be done? im also using a butcher's war clever to gather leathers (and the script see's them in my pack and put them on the ground just like the fish steaks just had to add it to the script). But beside moving to corpse and looting, plus using war cleaver. the script works great! love it

[Experience]

Possibly but there's no where I could code it on my server

[krypher]

ok well if it help my server is login.wakened.net port 2593 at www.wakened.net/.